Автоматизация сетевых настроек

[Zerbog 0]

 

Скрипт рульный, рабочий...НО...

при запуске подготовленного скрипта settings_X.X.X.X.vbs вываливаеться сообщение об синтаксической ошибке в строке 72(74), символ 1 - это НЕКСТ

 

vbCritical, "Ошибка настройки")

End If

End If

if Button = vbCancel Then

WScript.Quit

End if

Next <----- SYNTAX ERROR

 

WScript.Quit

 

Подскажите в чем может быть трабла, хотя внешний вид скрипта безупречен

[XoRe 0]

2Zerbog:

Имхо, где-то вы чего-то не так прописали в vbs скрипте.

Ось случаем не vista? )

[Arkeston 0]

Я написал скрипт на NSIS, за исключением вышеприведенных настроек:

 

Делает следующее:

 

Ставит настроенный UniChat с ником = имя пользователя компа

Ставит Jabber клиент PSI

Ставит на рабочий стол ярлыки на ресурсы сетей, прописывает в реестре маршруты выбирая необходимый шлюз из ip адреса адаптера (отсекаются левые адаптеры типа BT) в реестр и(или) bat'ом, базовые настройки безопасности.

Ставит Radmin с ярлыками для тупых пользователей (есть возможность прописать и пароль администратора)

Устанавливает DrWeb и запускает службу

 

Пока это.

 

Не вопрос сделать дискету - инсталлятор сети, с подсасыванием необходимых компонентов с ftp. (Эх, красота, приду, запущю, все настройки сохранятся и вручу дискету на случай переустановки винды).

 

Сейчас разбираюсь над лучшим способом создать VPN подключение автоматически. В планах сделать скрипт на сервере для автоматического создания billing, mail , jabber аккаунтов.

 

 

Но! Я потратил время для создания этого, а под боком сидят конкуренты из моей сети которые спят и видят что бы я сделал им тоже самое.

Так что я рассматриваю варианты - или пока бесплатно компилировать инсталляторы для вашей сети по запросу или тоже самое, но за денежку (символическая сумма на WebMoney меня устроит).

 

Какие ваши мысли?

[jone88 0]

мой скриптик

 

ищет среди сетевых карт на компе абонента правилный мак-адрес и адаптеру с правилным мак адресом присваивает ип и прочая

список ип-адресов в секции case по аналогии.

 

Отличие- вообще ничего абоненту вводить и выбирать не надо)

 

 

On Error Resume Next
Dim objWMIService
Dim objNetAdapter
Dim strComputer
Dim strGateway
Dim strGatewayMetric
Dim strAddress
Dim strIPAddress
Dim strSubnetMask
Dim colNetAdapters
Dim errEnable
Dim errGateways
Dim objShell
Dim intValue
Dim Button
Dim arrNewDNSServerSearchOrder
Dim colNicConfigs
Dim objNicConfig
Dim strDNSServer
Dim intSetDNSServers
Dim strMask
Dim strGate
Dim strDns
Dim ip 
dim mc
dim gate
dim mc2

strComputer = "."
mc2="1"
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colNetAdapters = objWMIService.ExecQuery ("Select * from Win32_NetworkAdapterConfiguration where IPEnabled = TRUE")

for Each objNetAdapter in colNetAdapters

mc=objNetAdapter.MACAddress


select case mc


case "00:15:F2:1C:AF:CA"
ip="192.168.5.128"
gate ="192.168.5.1"
mc2=mc

case "00:1A:92:E1:2A:57"
ip="192.168.5.123"
gate ="192.168.5.1"
mc2=mc
--------
-------
--------
end select

next



if mc2= "1" then 
msgbox("Ваша сетевая карта не зарегистрирована в сети. Обратитесь в службу поддержки по тел. 8-901-333-444-555")
WScript.Quit
end if





strAddress = (ip)
strMask = ("255.255.255.0")
strGate = (gate)
strDns = ("10.1.1.1")
strIPAddress = Array(strAddress)
strSubnetMask = Array(strMask)
strGateway = Array(strGate)
strGatewayMetric = Array(1)
arrNewDNSServerSearchOrder = Array(strDns)







Button = MsgBox ("Сейчас вам будет предложено применить настройки к зарегистрированной в Сети сетевой карте" & vbCRLF & _
"Нажмите ''Ok'' для настройки сетевой карты" & vbCRLF & _
"Перед тем, как нажать кнопку ''Ok'' убедитесь, что подключение к локальной сети включено и сетевой кабель вставлен в сетевую карту." & vbCRLF & _
"Без этих условий настройки не сохранятся." & vbCRLF & vbCRLF & _
"Применяемые настройки: " & vbCRLF & _
"IP: " & strAddress & vbCRLF & _
"Маска: " & strMask & vbCRLF & _
"Шлюз: " & strGate & vbCRLF & _
"DNS: " & strDns & vbCRLF, vbOKOnly + vbInformation, "Настройка подключения")



for Each objNetAdapter in colNetAdapters
if objNetAdapter.MACAddress=mc2 then
errEnable = objNetAdapter.EnableStatic(strIPAddress, strSubnetMask)
errGateways = objNetAdapter.SetGateways(strGateway, strGatewaymetric)
intSetDNSServers = objNetAdapter.SetDNSServerSearchOrder(arrNewDNSServerSearchOrder)
objNetAdapter.SetTCPIPNetBIOS(2)

If errEnable = 0 Then
 Button = MsgBox ("IP изменен на: " & strAddress & vbCRLF & _
 "Маска изменена на: " & strMask & vbCRLF & _
 "Шлюз изменен на: " & strGate & vbCRLF & _
 "DNS изменен на: " & strDns & vbCRLF & vbCRLF & "Для сетевой карты: " & vbCRLF & objNetAdapter.Caption, _
 vbOKOnly + vbInformation, "Сохранение настроек")

Else
 Button = MsgBox ("Ошибка. Сетевой кабель не подключен или сетевая карточка не включена" & vbCRLF & _
 "Файл настройки можно скачать по адресу:" & vbCRLF & _
 "local", vbOKOnly + vbCritical, "Ошибка настройки")
End If
End If
if Button = vbCancel Then
  WScript.Quit
End if
Next

WScript.Quit

 

 

Второй скриптик выдирает инфу о сетевушках и адресах на компе абонента и пишет все в файл:

 

 

Dim fso, ts, f1

strComputer = "."

Set fso = CreateObject("Scripting.FileSystemObject")


Const ForWriting = 2

Set objTextFile = fso.OpenTextFile("c:\adressIp.txt", ForWriting,true)


Set objWMIService = GetObject("winmgmts:" _
   & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colAdapters = objWMIService.ExecQuery _
   ("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")

n = 1



For Each objAdapter in colAdapters
  objTextFile.writeline "Network Adapter " & n
  objTextFile.writeline "================="
  objTextFile.writeline "  Description: " & objAdapter.Description

  objTextFile.writeline "  Physical (MAC) address: " & objAdapter.MACAddress
  objTextFile.writeline "  Host name:              " & objAdapter.DNSHostName

  If Not IsNull(objAdapter.IPAddress) Then
     For i = 0 To UBound(objAdapter.IPAddress)
        objTextFile.writeline "  IP address:             " & objAdapter.IPAddress(i)
     Next
  End If

  If Not IsNull(objAdapter.IPSubnet) Then
     For i = 0 To UBound(objAdapter.IPSubnet)
        objTextFile.writeline "  Subnet:                 " & objAdapter.IPSubnet(i)
     Next
  End If

  If Not IsNull(objAdapter.DefaultIPGateway) Then
     For i = 0 To UBound(objAdapter.DefaultIPGateway)
        objTextFile.writeline "  Default gateway:        " & _
            objAdapter.DefaultIPGateway(i)
     Next
  End If

  objTextFile.writeline
  objTextFile.writeline "  DNS"
  objTextFile.writeline "  ---"
  objTextFile.writeline "    DNS servers in search order:"

  If Not IsNull(objAdapter.DNSServerSearchOrder) Then
     For i = 0 To UBound(objAdapter.DNSServerSearchOrder)
        objTextFile.writeline "      " & objAdapter.DNSServerSearchOrder(i)
     Next
  End If

  objTextFile.writeline "    DNS domain: " & objAdapter.DNSDomain

  If Not IsNull(objAdapter.DNSDomainSuffixSearchOrder) Then
     For i = 0 To UBound(objAdapter.DNSDomainSuffixSearchOrder)
        objTextFile.writeline "    DNS suffix search list: " & _
            objAdapter.DNSDomainSuffixSearchOrder(i)
     Next
  End If

  objTextFile.writeline
  objTextFile.writeline "  DHCP"
  objTextFile.writeline "  ----"
  objTextFile.writeline "    DHCP enabled:        " & objAdapter.DHCPEnabled
  objTextFile.writeline "    DHCP server:         " & objAdapter.DHCPServer

  If Not IsNull(objAdapter.DHCPLeaseObtained) Then
     utcLeaseObtained = objAdapter.DHCPLeaseObtained
     strLeaseObtained = WMIDateStringToDate(utcLeaseObtained)
  Else
     strLeaseObtained = ""
  End If
  objTextFile.writeline "    DHCP lease obtained: " & strLeaseObtained

  If Not IsNull(objAdapter.DHCPLeaseExpires) Then
     utcLeaseExpires = objAdapter.DHCPLeaseExpires
     strLeaseExpires = WMIDateStringToDate(utcLeaseExpires)
  Else
     strLeaseExpires = ""
  End If
  objTextFile.writeline "    DHCP lease expires:  " & strLeaseExpires

  objTextFile.writeline
  objTextFile.writeline "  WINS"
  objTextFile.writeline "  ----"
  objTextFile.writeline "    Primary WINS server:   " & objAdapter.WINSPrimaryServer
  objTextFile.writeline "    Secondary WINS server: " & objAdapter.WINSSecondaryServer
  objTextFile.writeline

  n = n + 1

Next

Function WMIDateStringToDate(utcDate)
  WMIDateStringToDate = CDate(Mid(utcDate, 5, 2)  & "/" & _
      Mid(utcDate, 7, 2)  & "/" & _
          Left(utcDate, 4)    & " " & _
              Mid (utcDate, 9, 2) & ":" & _
                  Mid(utcDate, 11, 2) & ":" & _
                     Mid(utcDate, 13, 2))
End Function

 

 

компилить в бинарник все это можно с помошью проги ExeScript- варез, гугль в помошь

[Roofa 0]

Спасибо большое.

Подскажите пожалуйста как написать еще скриптик что бы он автоматически прописывал домашнюю страничку?

[Gozya 0]

REM IP i maska...
netsh interface ip set address name="Simnet" source=static addr=10.7.23.25 mask=255.255.0.0
REM Shluz...
netsh interface ip set address name="Simnet" gateway=10.7.0.128 gwmetric=0
REM DNS1...
netsh interface ip set dns name="Simnet" source=static addr=10.7.0.254 register=PRIMARY
REM DNS2...
netsh interface ip set dns name="Simnet" source=static addr=192.168.0.1 register=2
REM WINS...
netsh interface ip set wins name="Simnet" source=static addr=10.7.0.128

REM Finish...

Вот такой батник есть. Но ни как не выходит сделать, чтоб заполнялась графа Альтернативный DNS-сервер. :tongue:

Подскажите плз :=

пробуй в таком виде

netsh interface ip set dns name="Подключение по локальной сети" source=static addr=172.16.8.2 register=PRIMARY
netsh interface ip add dns name="Подключение по локальной сети" addr=172.16.8.100 index=2
netsh interface ip add dns name="Подключение по локальной сети" addr=172.16.8.1 index=3
netsh interface ip add dns name="Подключение по локальной сети" addr=208.67.222.222 index=4

[µ®•©®¤w¶ 0]

Имеется прога для настройки сети на клиентской стороне!

Состоит из одного бинарника в 38 Кб.

Предназначена (На данный момент) тольк для настройки сетей с ДХЦП.

Принцип работы такой:

 

1. Пинг сервака в локале (Лучще ДХЦП сервер);

2. Если пинг идет, то и парится собно нечего и мы выходим с сообщением что все ОК;

3. Если же пинг не ходит пробуем настроить;

4. Настройка:

4.1. Проходим по всем активным, в данный момент, подключениям и пробуем их настроить;

4.1.1. Проверяем службу "DHCP-Клиент" если не запущена - запускаем и ставим тип запуска АВТО;

4.1.2. Заставляем получить адрес;

4.1.3. Пингуем серв и если он отвечает - выходим;

4.2. Проходим по списку сетевых устройств Винь32 (Физических устройств) и пробуем их настроить;

4.2.1. Если устройство отключено - включаем;

4.2.2. Получаем сетевое подключение привязаное к этому адаптеру;

4.2.3. Настраиваем. Если сетевой кабель не подключен, пропускаем адаптер;

4.2.4. Пинг серва и выход если все в поряде;

5. Пинг серва, для проверки результата настройки (Лишний пинг не повредит)

5.1. Если пинг идет - выходим

5.2. Если пинг не идет, выводим все сетевые интерфейсы (активные) кторые пренадлежат ФИЗИЧЕСКОМУ сетевому адаптеру, и выводим инфу о нем (Имя, МАК, Состояние кабеля) так же выводится сообщение о том, что вот теперь можно и Одмина понапрягать.

 

Планирую прикрутить плагины, типа что бы каждый мог адаптировать тулзу к своей сети.

[Romeshik 144]

Вау супер, как раз искал такую весчь! Скрипы отличные.

Ребята а может кто нибуть подсказать как вписать в скрипт создание ВПН-подключения, с настройками логина пассворда, шифрования.?

 

Я просто в сетке настраиваю все вручную, потом создаю ВПН-подключение, настраиваю его (снимаю галочку запрашивать логин и пароль) и бросаю ярлык в автозагрузку.

Таким образом при включении компа у юзера у него автоматом устанавливается ВПН соединение и человек без лишних телодвижений уже в интернете.

А вот как бы все это скриптиком автоматизировать?

[Pretender 5]

Имеется прога для настройки сети на клиентской стороне!

Состоит из одного бинарника в 38 Кб.

Предназначена (На данный момент) тольк для настройки сетей с ДХЦП.

Принцип работы такой:

 

1. Пинг сервака в локале (Лучще ДХЦП сервер);

2. Если пинг идет, то и парится собно нечего и мы выходим с сообщением что все ОК;

3. Если же пинг не ходит пробуем настроить;

4. Настройка:

4.1. Проходим по всем активным, в данный момент, подключениям и пробуем их настроить;

4.1.1. Проверяем службу "DHCP-Клиент" если не запущена - запускаем и ставим тип запуска АВТО;

4.1.2. Заставляем получить адрес;

4.1.3. Пингуем серв и если он отвечает - выходим;

4.2. Проходим по списку сетевых устройств Винь32 (Физических устройств) и пробуем их настроить;

4.2.1. Если устройство отключено - включаем;

4.2.2. Получаем сетевое подключение привязаное к этому адаптеру;

4.2.3. Настраиваем. Если сетевой кабель не подключен, пропускаем адаптер;

4.2.4. Пинг серва и выход если все в поряде;

5. Пинг серва, для проверки результата настройки (Лишний пинг не повредит)

5.1. Если пинг идет - выходим

5.2. Если пинг не идет, выводим все сетевые интерфейсы (активные) кторые пренадлежат ФИЗИЧЕСКОМУ сетевому адаптеру, и выводим инфу о нем (Имя, МАК, Состояние кабеля) так же выводится сообщение о том, что вот теперь можно и Одмина понапрягать.

 

Планирую прикрутить плагины, типа что бы каждый мог адаптировать тулзу к своей сети.

поделись програмулькой, она как раз разруливает проблемы связанные с криворукостью пользователей

[µ®•©®¤w¶ 0]

поделись програмулькой, она как раз разруливает проблемы связанные с криворукостью пользователей

Для этого собсно и писалась.

Обязательно поделюсь, только когда все будет готово! Полуфабрикатами не промышляю

[Pretender 5]

Для этого собсно и писалась.

Обязательно поделюсь, только когда все будет готово! Полуфабрикатами не промышляю

ну ждемс

 

Вау супер, как раз искал такую весчь! Скрипы отличные.

Ребята а может кто нибуть подсказать как вписать в скрипт создание ВПН-подключения, с настройками логина пассворда, шифрования.?

 

Я просто в сетке настраиваю все вручную, потом создаю ВПН-подключение, настраиваю его (снимаю галочку запрашивать логин и пароль) и бросаю ярлык в автозагрузку.

Таким образом при включении компа у юзера у него автоматом устанавливается ВПН соединение и человек без лишних телодвижений уже в интернете.

А вот как бы все это скриптиком автоматизировать?

в 2003 винде есть какая-то тулзятина которая автоматизарует настройку впн, только созданный ею бинарник не работает под виста х64

[Romeshik 144]

Учитывая что у 80% стоит ХР-юша, и добавив то что 50% владельцев Висты перебивают ее опять таки на ХР-юшу...мне бы такой скриптик именно по ХР и именно под 32 битную.

[Pretender 5]

Учитывая что у 80% стоит ХР-юша, и добавив то что 50% владельцев Висты перебивают ее опять таки на ХР-юшу...мне бы такой скриптик именно по ХР и именно под 32 битную.

кинь в пм адрес мыла брошу заготовку с небольшой инструкцией как собрать

[winbox 15]

оцените

 

'-- Network setup script version 2.03
'--

cr = +chr(13)+chr(10) 
L_Welcome_MsgBox_Message_Text   = _
 "Укажите какие пункты настройки необходимо выполнить:"&cr&_
 "1. Отключить службу 'Обозреватель компьютеров'"&cr&_
 "2. Отключить службу 'Веб-клиент'"&cr&_
 "3. Отключить службу 'NetMeeting Remote Desktop Sharing'"&cr&_
 "4. Отключить службу 'Диспетчер сеанса справки для удаленного рабочего стола'"&cr&_
 "5. Отключить службу 'Удаленный реестр (Remote Registry Service)'"&cr&_
 "6. Отключить службу 'Служба обнаружения SSDP (SSDP Discovery Service)'"&cr&_
 "7. Отключить службу 'Службы терминалов (Terminal Services)'"&cr&_
 "8. Отключить службу 'Служба индексирования (Indexing Service)'"&cr&_
 "9. Отключить прокси сервер '"&cr&_
 "A. Создать ВПН подключение к 'ProNeT'"&cr&_
 "B. Настроить Брандмауэр Windows"&cr&_
 "C. Установить рабочую группу ProNeT"
L_Welcome_MsgBox_Title_Text = "Настройка сети.Версия 2.02 (с) ProNeT"

so_entry = "[ProNeT]"&cr&_
           "Encoding=1"&cr&_
           "Type=2"&cr&_
           "AutoLogon=0"&cr&_
           "UseRasCredentials=1"&cr&_
           "DialParamsUID=315453"&cr&_
           "Guid=CC34DB8F83C00649A4153A152484B0CB"&cr&_
           "BaseProtocol=1"&cr&_
           "VpnStrategy=2"&cr&_
           "ExcludedProtocols=0"&cr&_
           "LcpExtensions=1"&cr&_
           "DataEncryption=8"&cr&_
           "SwCompression=1"&cr&_
           "NegotiateMultilinkAlways=0"&cr&_
           "SkipNwcWarning=0"&cr&_
           "SkipDownLevelDialog=0"&cr&_
           "SkipDoubleDialDialog=0"&cr&_
           "DialMode=1"&cr&_
           "DialPercent=75"&cr&_
           "DialSeconds=120"&cr&_
           "HangUpPercent=10"&cr&_
           "HangUpSeconds=120"&cr&_
           "OverridePref=15"&cr&_
           "RedialAttempts=3"&cr&_
           "RedialSeconds=60"&cr&_
           "IdleDisconnectSeconds=0"&cr&_
           "RedialOnLinkFailure=0"&cr&_
           "CallbackMode=0"&cr&_
           "CustomDialDll="&cr&_
           "CustomDialFunc="&cr&_
           "CustomRasDialDll="&cr&_
           "AuthenticateServer=0"&cr&_
           "ShareMsFilePrint=0"&cr&_
           "BindMsNetClient=0"&cr&_
           "SharedPhoneNumbers=0"&cr&_
           "GlobalDeviceSettings=0"&cr&_
           "PrerequisiteEntry="&cr&_
           "PrerequisitePbk="&cr&_
           "PreferredPort=VPN6-0"&cr&_
           "PreferredDevice=Р_РёР_РёРїР_С_С' WAN (L2TP)"&cr&_
           "PreferredBps=0"&cr&_
           "PreferredHwFlow=1"&cr&_
           "PreferredProtocol=1"&cr&_
           "PreferredCompression=1"&cr&_
           "PreferredSpeaker=1"&cr&_
           "PreferredMdmProtocol=0"&cr&_
           "PreviewUserPw=1"&cr&_
           "PreviewDomain=0"&cr&_
           "PreviewPhoneNumber=0"&cr&_
           "ShowDialingProgress=1"&cr&_
           "ShowMonitorIconInTaskBar=1"&cr&_
           "CustomAuthKey=-1"&cr&_
           "AuthRestrictions=872"&cr&_
           "TypicalAuth=2"&cr&_
           "IpPrioritizeRemote=1"&cr&_
           "IpHeaderCompression=0"&cr&_
           "IpAddress=0.0.0.0"&cr&_
           "IpDnsAddress=0.0.0.0"&cr&_
           "IpDns2Address=0.0.0.0"&cr&_
           "IpWinsAddress=0.0.0.0"&cr&_
           "IpWins2Address=0.0.0.0"&cr&_
           "IpAssign=1"&cr&_
           "IpNameAssign=1"&cr&_
           "IpFrameSize=1006"&cr&_
           "IpDnsFlags=0"&cr&_
           "IpNBTFlags=1"&cr&_
           "TcpWindowSize=0"&cr&_
           "UseFlags=0"&cr&_
           "IpSecFlags=0"&cr&_
           "IpDnsSuffix="&cr&_
           "NETCOMPONENTS="&cr&_
           "ms_server=0"&cr&_
           "ms_msclient=0"&cr&_
           "ms_psched=1"&cr&_
           "cntx_vpcnets2=0"&cr&_
           "MEDIA=rastapi"&cr&_
           "Port=VPN6-0"&cr&_
           "Device=Р_РёР_РёРїР_С_С' WAN (L2TP)"&cr&_
           "DEVICE=vpn"&cr&_
           "PhoneNumber=10.1.1.100"&cr&_
           "AreaCode="&cr&_
           "CountryCode=1"&cr&_
           "CountryID=1"&cr&_
           "UseDialingRules=0"&cr&_
           "Comment="&cr&_
           "LastSelectedPhone=0"&cr&_
           "PromoteAlternates=0"&cr&_
           "TryNextAlternateOnFail=1"&cr

options =  InputBox(L_Welcome_MsgBox_Message_Text, _
              L_Welcome_MsgBox_Title_Text, _
      "12345689ABC" )
If options = "" Then
  WScript.Quit
End If

Dim WSHShell, fso, fh, AUDesktop, lnk, pbk

Set WSHShell = WScript.CreateObject("WScript.Shell")

If InStr(options, "1") > 0 then
' Обозреватель компьютеров
WShShell.Run "sc stop Browser", 7, true
WShShell.Run "sc config Browser start= disabled", 7, true
end if

If InStr(options, "2") > 0 then
' Веб-клиент
WShShell.Run "sc stop WebClient",7,true
WShShell.Run "sc config WebClient start= disabled", 7, true
end if

If InStr(options, "3") > 0 then
' NetMeeting Remote Desktop Sharing
WShShell.Run "sc stop mnmsrvc", 7, true
WShShell.Run "sc config mnmsrvc start= disabled", 7, true
end if

If InStr(options, "4") > 0 then
' Диспетчер сеанса справки для удаленного рабочего стола
WShShell.Run "sc stop RDSessMgr", 7, true
WShShell.Run "sc config RDSessMgr start= disabled", 7, true
end if

If InStr(options, "5") > 0 then
' Удаленный реестр (Remote Registry Service)
WShShell.Run "sc stop RemoteRegistry", 7, true
WShShell.Run "sc config RemoteRegistry start= disabled", 7, true
end if

If InStr(options, "6") > 0 then
' Служба обнаружения SSDP (SSDP Discovery Service)
WShShell.Run "sc stop SSDPSRV", 7, true
WShShell.Run "sc config SSDPSRV start= disabled", 7, true
end if

If InStr(options, "7") > 0 then
' Службы терминалов (Terminal Services)
WShShell.Run "sc stop TermService", 7, true
WShShell.Run "sc config TermService start= disabled", 7, true
end if

If InStr(options, "8") > 0 then
' Служба индексирования (Indexing Service)
WShShell.Run "sc stop cisvc", 7, true
WShShell.Run "sc config cisvc start= disabled", 7, true
end if

If InStr(options, "9") > 0 then

dim WShell
set WShell = Wscript.CreateObject("Wscript.Shell")

WShell.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyServer", "10.1.1.1:3128", "REG_SZ"
'-- WShell.RegWrite "HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyServer", "proxy_name:8080", 

"REG_SZ"

Set WShell = Nothing

WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyEnable", 0, "REG_DWORD"
'-- WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyServer", proxy
'-- WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyOverride", ""
'-- WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\DisablePasswordCaching", 1, "REG_DWORD"

end if

'-- If InStr(options, "9") > 0 then
' Routing
'-- WShShell.Run "route add -p 193.111.242.0 mask 255.255.255.0 193.111.241.1"
'-- WShShell.Run "route add -p 193.111.243.0 mask 255.255.255.0 193.111.241.1"
'-- end if

If InStr(options, "A") > 0 then
' VPN
WShShell.Run "rasphone -r ""ProNeT""", 7, true

Set fso = CreateObject("Scripting.FileSystemObject")
pbk = "%AllUsersProfile%\Application Data\Microsoft\Network\Connections\Pbk\rasphone.pbk"
pbk = WSHShell.ExpandEnvironmentStrings(pbk)

Set fh = fso.OpenTextFile(pbk, 8, true)
fh.Write(so_entry)
fh.Close

' Ярлык
AUDesktop = WSHShell.SpecialFolders("AllUsersDesktop")

Set lnk = WSHShell.CreateShortcut(AUDesktop & "\ProNeT.lnk")

lnk.Description = "ProNeT"
lnk.Arguments = "-d ""ProNeT"""
lnk.TargetPath = "rasphone"
lnk.Save
WShShell.Run "explorer.exe ::{7007ACC7-3202-11D1-AAD2-00805FC1270E}"
end if

If InStr(options, "B") > 0 then
' ICMP
WShShell.Run "netsh firewall set opmode mode= ENABLE exceptions= ENABLE", 7, true
WShShell.Run "netsh firewall set icmpsetting type= 8 mode= ENABLE", 7, true
end if

If InStr(options, "C") > 0 then
' WORKGROUP
strWorkgroup   = "ProNeT"
Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName
Set objComputer = GetObject("winmgmts:{impersonationLevel=Impersonate}!\\" & _
     strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" _
     & strComputer & "'")
ReturnValue = objComputer.JoinDomainOrWorkGroup(strWorkgroup, _
 NULL, NULL , NULL, 0)
end if

WScript.Echo( "Настройки произведены. Проверьте подключение")

 

vbs

 

как вам мое творение ?

[Maxxx 444]

Покажите ехешку.

[blackjack 244]

это vbs нет екзешек.

[gall 6]

это vbs нет екзешек.

есть, делать прогой ExeScript